home *** CD-ROM | disk | FTP | other *** search
/ Network PC / Network PC.iso / amiga utilities / communication / internet / amitcp3.0b / src.lha / src / libs / usergroup / make_fd.awk < prev    next >
Encoding:
AWK Script  |  1996-09-08  |  6.2 KB  |  246 lines
  1. # Hey Emacs! This file might as well be -*- C -*-
  2. #
  3. # make_fd.awk -- create prototype, FD and pragma files
  4. #
  5. # Author: ppessi <Pekka.Pessi@hut.fi>
  6. #
  7. # Copyright © 1993, 1994 AmiTCP/IP Group, <AmiTCP-Group@hut.fi>
  8. #                   Helsinki University of Technology, Finland.
  9. #
  10. # Created      : Mon Nov 29 21:14:58 1993 ppessi
  11. # Last modified: Sat Feb 12 02:57:44 1994 ppessi
  12. #
  13. # $Id: make_fd.awk,v 1.4 1994/02/17 02:23:05 ppessi Exp $
  14. #
  15. # $Log: make_fd.awk,v $
  16. # Revision 1.4  1994/02/17  02:23:05  ppessi
  17. # Changed the defines for include files
  18. #
  19. # Revision 1.3  1994/01/21  08:32:32  ppessi
  20. # Added a "what" variable to determine the conversion result
  21. #
  22. # Revision 1.2  1994/01/21  05:00:16  ppessi
  23. # Fancier blurbs.
  24. #
  25. #
  26.  
  27. # 
  28. # Each prototype must in the form
  29. # ASM type name(REG(rn) type name);
  30. # Do not forget argument name!
  31. # The tagcall stub must be given in the next line of 
  32. # /* TAGCALL tag_call_stub_name */
  33. #
  34.  
  35. BEGIN {
  36.   stderr = "console:";
  37.  
  38.   if (what != "protos" && what != "pragmas" && what != "fd") {
  39.     print "but what to do?" > stderr;
  40.     exit(10);
  41.   }
  42.  
  43.   library = "usergroup";
  44.   basename = "UserGroupBase";
  45.   fds = "fd/"library"_lib.fd";
  46.   pragmaname = "pragmas/"library"_pragmas.h"
  47.   pragmas = "include/"pragmaname;
  48.   outputname = "clib/"library"_protos.h";
  49.   define = toupper(outputname);
  50.   gsub("[/.]", "_", define);
  51.   output = "include/"outputname;
  52.  
  53.   libprefix = "^R_";
  54.   libfunctype = "^ASM$";
  55.  
  56.   libincludename = "libraries/"library".h";
  57.   libincludedefine = toupper(libincludename);
  58.   gsub("[/.]", "_", libincludedefine);
  59.   libinclude = "include/"libincludename;
  60.  
  61.   libincludename1 = "pwd.h";
  62.   libincludedefine1 = toupper(libincludename1);
  63.   gsub("[/.]", "_", libincludedefine1);
  64.  
  65.   libincludename2 = "grp.h";
  66.   libincludedefine2 = toupper(libincludename2);
  67.   gsub("[/.]", "_", libincludedefine2);
  68.  
  69.   copyright = \
  70.     "**\tCopyright (c) 1993 AmiTCP/IP Group, <AmiTCP-Group@hut.fi>\n"\
  71.     "**\t    Helsinki University of Technology, Finland.\n"\
  72.     "**\t    All rights reserved.\n";
  73.  
  74.   state = 0;
  75.   priv = 1;
  76.   public = 2;
  77.  
  78.   release="$Release$";
  79.   rcsdate="$Date: 1994/02/17 02:23:05 $";
  80. }
  81.  
  82. state == 0 && $0 ~ /\$Date/ {
  83.   rcsdate = $0;
  84.   sub(/^[^$]*/, "", rcsdate);
  85.   sub(/[^$]*$/, "", rcsdate); 
  86. }
  87.  
  88. state == 0 && $0 ~ /\$Revision/ {
  89.   rcsid = $0;
  90.   sub(/^[^$]*/, "", rcsid);
  91.   sub(/[^$]*$/, "", rcsid); 
  92.  
  93.   fnfmt = "**\t$Filename: %s $\n";
  94.   rcsfmt = "**\t%s\n";
  95.   
  96.   if (what == "protos") {
  97.     protosblurb="**\n**\tC prototypes for %s.library\n**\n";
  98.     printf("#ifndef %s\n", define);
  99.     printf("#define %s\n", define);
  100.     printf("/*\n");
  101.     printf(fnfmt, outputname );
  102.     printf(rcsfmt, release); 
  103.     printf(rcsfmt, rcsid); 
  104.     printf(rcsfmt, rcsdate); 
  105.     printf(protosblurb, library);
  106.     printf(copyright); 
  107.     printf("*/\n");
  108.     printf("\n#ifndef %s\n#include \<%s\>\n#endif\n", 
  109.        libincludedefine, libincludename); 
  110.     printf("\n#ifndef %s\n#include \<%s\>\n#endif\n", 
  111.        libincludedefine1, libincludename1); 
  112.     printf("\n#ifndef %s\n#include \<%s\>\n#endif\n", 
  113.        libincludedefine2, libincludename2); 
  114.   } else if (what == "pragmas") {
  115.     pragmablurb="**\n**\tPragmas file for %s.library\n**\n";
  116.     printf("/*\n");
  117.     printf(fnfmt, pragmaname );
  118.     printf(rcsfmt, release); 
  119.     printf(rcsfmt, rcsid); 
  120.     printf(rcsfmt, rcsdate); 
  121.     printf(pragmablurb, library);
  122.     printf(copyright); 
  123.     printf("*/\n");
  124.   } else if (what == "fd") {
  125.     fdblurb="**\n**\tFD file for %s.library\n**\n";
  126.     printf("**\n");
  127.     printf(fnfmt, fds );
  128.     printf(rcsfmt, release); 
  129.     printf(rcsfmt, rcsid); 
  130.     printf(rcsfmt, rcsdate); 
  131.     printf(fdblurb, library);
  132.     printf(copyright); 
  133.     printf("**\n");
  134.     printf("##base _%s\n##bias 30\n##public\n", basename);
  135.   }
  136.   base = 30;
  137.   state = public;
  138.   next;
  139. }
  140.  
  141. state != 0 && $1 ~ libfunctype {
  142.   if (!match($0, /[A-Za-z][A-Za-z0-9_]*\(/)) {
  143.     printf("$0: No function name") >stderr;
  144.     exit 1;
  145.   }
  146.   fname = substr($0, RSTART, RLENGTH - 1);
  147.   sub(libprefix, "", fname);
  148.   rtype = substr($0, 1, RSTART - 1);
  149.   sub(/^[^     ]* */, "", rtype);
  150.  
  151.   registerless = rtype""fname"(";
  152.  
  153.   arglist = $0;
  154.  
  155.   argnames = ""; reglist = ""; twoline = 0;
  156.  
  157.   sub(/^[^(]*\(/, "", arglist); 
  158.   sub(/\)[^)]*$/, "", arglist); 
  159.  
  160.   argn = split(arglist, args, ",");
  161.  
  162.   if (argn != 1 || args[1] !~ "^void$") {
  163.     pragmacode = sprintf("%02X", argn);
  164.  
  165.     for (i = 1; i < argn + 1; i++) {
  166.       sub(/ */, "", args[i]);
  167.       apn = split(args[i], ap, "[ *]+");
  168.       if (match(ap[1], /^REG\(d[0-7]\)$/)) {
  169.     pragmacode = sprintf("%X%s", substr(ap[1], 6, 1), pragmacode);
  170.       } else if (match(ap[1], /^REG\(a[0-7]\)$/)) {
  171.     pragmacode = sprintf("%X%s", substr(ap[1], 6, 1) + 8, pragmacode);
  172.       } else {
  173.     printf("%s: argument %s has no register\n", fname, ap[apn]) > stderr;
  174.     exit 1;
  175.       }
  176.       
  177.       argnames=argnames""ap[apn];
  178.       reglist=reglist""substr(ap[1], 5, 2);
  179.       sub(/^REG\(..\) */, "", args[i]);
  180.       lastrl = registerless;
  181.       if (!twoline && length(registerless""args[i]) > 76) {
  182.     twoline = 1;
  183.     registerless=registerless"\n        ";
  184.       }
  185.       registerless = registerless""args[i]
  186.       if (i < argn) {
  187.     argnames = argnames", ";
  188.     reglist = reglist"/";
  189.     registerless = registerless", ";
  190.       }
  191.     }
  192.   } else {
  193.     registerless = registerless"void";
  194.     pragmacode = "00";
  195.   }
  196.  
  197.   if (what == "protos") {
  198.     printf("%s);\n", registerless);
  199.   } else if (what == "pragmas") {
  200.     printf("#pragma libcall %s %s %X %s\n", 
  201.        basename, fname, base, pragmacode);
  202.   } else if (what == "fd") {
  203.     printf("%s(%s)(%s)\n", fname, argnames, reglist);
  204.   }
  205.   base += 6;
  206.   next;
  207. }
  208.  
  209. state != 0 && $1 ~ /^\/\*$/ && $2 == "TAGCALL" {
  210.   sub(fname, $3, lastrl);
  211.   if (what == "protos") {
  212.     printf("%s ...);\n", lastrl);
  213.   } else if (what == "pragmas") {
  214.     printf("#pragma tagcall %s %s %X %s\n", 
  215.        basename, $3, base - 6, pragmacode);
  216.   }
  217.   next;
  218. }
  219.  
  220. state != 0 && $1 ~ /^\/\*$/ {
  221.   if (what == "protos") {
  222.     printf "%s\n", $0;
  223.   } else if (what == "pragmas") {
  224.     printf "%s\n", $0;
  225.   } else if (what == "fd") {
  226.     sub(/\/\*/, "*------", $0);
  227.     sub(/\*\//, "------*", $0);
  228.     print $0;
  229.   }
  230.   next;    
  231. }
  232.  
  233. state != 0 {
  234.   if (what == "protos") {
  235.     print $0;
  236.   }
  237. }
  238.  
  239. END {
  240.   if (what == "protos") {
  241.     printf("\n#endif /* %s */\n", define);
  242.   } else if (what == "fd") {
  243.     printf("##end\n")
  244.   } 
  245. }
  246.